<Программа> ::= <Оператор> <Список операторов>

<Список операторов> ::= lambda | <Оператор> <Список операторов>

<Оператор> ::= <Объявление переменной>;

| <Объявление и определение переменной>;

| <Объявление массива>;

| <Объявление и определение массива>;

| <Условие if>

| <Присваивание>;

| <Цикл while>

| <Ввод с консоли>;

| <Вывод в консоль>;

<Объявление переменной> ::= int идентификатор

| real идентификатор

<Объявление и определение переменной> ::= int идентификатор = <Выражение>

| real идентификатор = <Выражение>

<Объявление массива> ::= int [ <Выражение> ] идентификатор

| real [ <Выражение> ] идентификатор

<Объявление и определение массива> ::= int [] идентификатор = { <Инициализаторы> }

| real [] идентификатор = { <Инициализаторы> }

<Инициализаторы> ::= <Выражение>

| <Инициализаторы> , <Выражение>

<Условие if> ::= if ( <Проверка равенства> ) <Блок> <Альтернативное действие>

<Альтернативное действие> ::= else <Блок> | lambda

<Блок> ::= { <Список операторов> }

<Присваивание> ::= идентификатор = <Выражение>

| идентификатор [ <Выражение> ] = <Выражение>

<Цикл while> ::= while ( <Проверка равенства> ) <Блок>

<Ввод с консоли> ::= input идентификатор [ <Выражение> ]

| input идентификатор

<Вывод в консоль> ::= output идентификатор

| output идентификатор [ <Выражение> ]

<Проверка равенства> ::= <Выражение> == <Выражение>

| <Выражение> < <Выражение>

| <Выражение> > <Выражение>

| <Выражение> ! <Выражение>

<Выражение> ::= <Терм>

| <Выражение> + <Терм>

| <Выражение> - <Терм>

<Терм> ::= <Фактор>

| <Терм> \* <Фактор>

| <Терм> / <Фактор>

<Фактор> ::= число

| идентификатор

| идентификатор [ <Выражение> ]

| ( <Выражение> )